Go Back   The macosxhints Forums > Working with OS X > Tweaking OS X / Wish List



Reply
 
Thread Tools Display Modes
Old 03-29-2005, 02:15 PM   #1
mclbruce
Hall of Famer
 
Join Date: Mar 2002
Posts: 3,878
Easily move photos from email to iPhoto

When I'm in iPhoto it's easy to select a photo or two and click the email button and an email message gets created with the photos attached.

I wish it was just as easy to put photos received in email into iPhoto. Select the email message, press a button or key combo, and the photos attached to the message are added to iPhoto.

I'm thinking that this could be done via AppleScript, with scripts available for Apple's Mail, Entourage, etc. I have done some looking around on the web but haven't seen anything that does this.
mclbruce is offline   Reply With Quote
Old 03-29-2005, 02:40 PM   #2
CAlvarez
Hall of Famer
 
Join Date: Sep 2004
Location: Phoenix, AZ
Posts: 4,975
I'm pretty sure drag and drop works here.
__________________
--
Carlos Alvarez, Phoenix, AZ

"MacBook Nano" (Lenovo S10) Atom 1.6/2GB/160GB Mac OS X 10.5.6
Gigabyte Quad Core 2.83GHz Hackintosh 4GB/500GB Mac OS X 10.6
MacBook Air 1.8/2GB/64GB SSD

http://www.televolve.com
CAlvarez is offline   Reply With Quote
Old 03-29-2005, 03:26 PM   #3
cudaboy_71
All Star
 
Join Date: Jan 2002
Location: sacramento, ca
Posts: 874
to an extent drag and drop works. if you have a msg with multiple photos though, any text between the photos (typically filenames or user descriptions) mess up the transfer, i.e. it doesnt work. if you just select one photo, it imports fine.

still could use some refining from the OS's standpoint.

[edit]
that got me to thinking and i had to open up iPhoto real quick. i had been selecting the photos from the message portion of the email. however, if you use the attachment turndown arrow at the top of the message, you can select all attached photos and drag'n drop fine. nice.

Last edited by cudaboy_71; 03-29-2005 at 03:29 PM.
cudaboy_71 is offline   Reply With Quote
Old 03-29-2005, 03:49 PM   #4
CAlvarez
Hall of Famer
 
Join Date: Sep 2004
Location: Phoenix, AZ
Posts: 4,975
That's what I was thinking, but I only recently discovered the "view all attachments" feature too, and should have specified.

I wish there was a way to import photos and text, and have the text become the description or photo info. THAT would save a lot of time when family/friends send me photos.
__________________
--
Carlos Alvarez, Phoenix, AZ

"MacBook Nano" (Lenovo S10) Atom 1.6/2GB/160GB Mac OS X 10.5.6
Gigabyte Quad Core 2.83GHz Hackintosh 4GB/500GB Mac OS X 10.6
MacBook Air 1.8/2GB/64GB SSD

http://www.televolve.com
CAlvarez is offline   Reply With Quote
Old 03-29-2005, 05:58 PM   #5
mclbruce
Hall of Famer
 
Join Date: Mar 2002
Posts: 3,878
Drag and drop from Entourage 2004 to the iPhoto 5 icon in my dock does not work. If iPhoto is open then yes I can drag into the library window. I'd still like to see this made simpler, both for me and for my clients.
mclbruce is offline   Reply With Quote
Old 03-30-2005, 09:01 AM   #6
cudaboy_71
All Star
 
Join Date: Jan 2002
Location: sacramento, ca
Posts: 874
i originally modified this script so my scans automatically got put in iPhoto. but, i believe it can be used as is for your use with entourage.

simply save your attachments to the 'watch folder' and they get imported into iPhoto. original script headers left for posterity. mine added just for clarity. read the code comments for additional info.

without much work, it could be modified as a 'drop app' to do the same thing from the dock.

however, modifications to files/libraries usually require the application to be running. so, i dont think there's any way around having iPhoto open. to me drag and drop seems easier.

Code:
(*
FolderOrg 1.3
by Doug Everly
DougEverly@mac.com


Version X 1.0
9/29/2002
Rewrote (simplified code) for use with OS X 10.2 Jaguar.

Version 1.3
11/10/1999

1/25/05 modified by cb_71 for importing scans directly to iPhoto. verified working with v. iPhoto 5.0.1

Description:
Attach this script to a folder. When items are added to the folder, the items will be placed inside of a folder label with the current date.
This is especially useful for organizing your "Downloads" folders.

modified description: attach this script to a folder. when items (scans) are placed in it, the script will put the photos in a folder with the current date. the script will then import the photos into iPhoto with an album with the current date.
*)


(* 
NOTE:  To toggle between trashing the originals in the finder & filing them in a 'date scanned' folder, change the trash_orig property below
*)

global the_path
global the_date
global the_file
property copy_checks_indicator : true
property item_check_delay_time : 1
property folder_check_delay_time : 2
property special_label_index : 7
property open_with_stuffit : true
property expand_folder : true
property debug_mode : false
property trash_orig : false


on adding folder items to this_folder after receiving added_items
	
	if (debug_mode is true) then say "Running action"
	-- format date for folder's name
	copy word 2 of ((current date) as text) & " " & word 3 of ((current date) as text) & " " & word 4 of ((current date) as text) to the_date
	copy (this_folder as text) & the_date to todaysfolder
	
	-- make today's folder if it does not already exist
	tell application "Finder"
		if (trash_orig is false) then
			if (folder todaysfolder exists) is not true then
				try
					make new folder at folder this_folder with properties {name:the_date}
					if (debug_mode is true) then say "Making folder"
				on error the_error
					display dialog the_error giving up after 30
				end try
				if current view of container window of folder this_folder is name then
					set the expanded of folder todaysfolder to true
				end if
			else
				if (debug_mode is true) then say "Folder already exists"
			end if
		end if
	end tell
	
	-- begin iPhoto processes
	-- make today's folder in iPhoto if it does not already exist
	repeat with i from 1 to the number of items in added_items
		set the_file to item i of added_items
		set the_path to POSIX path of the_file
		tell application "iPhoto"
			if (album the_date exists) is not true then
				try
					new album name the_date
					if (debug_mode is true) then say "Making folder"
				on error the_error
					display dialog the_error giving up after 30
				end try
			end if
			
			--import photos to today's album
			tell application "iPhoto"
				try
					import from POSIX path of the_file to album the_date
				on error the_error
					display dialog the_error giving up after 30
				end try
			end tell
			
			
		end tell
	end repeat
	
	-- move photos added to iPhoto into today's folder in finder
	if (trash_orig is false) then
		
		repeat with i from 1 to the number of items in added_items
			set the_file to item i of added_items
			tell application "Finder"
				if (file the_file exists) then
					try
						if (debug_mode is true) then say "Moving file to folder"
						
						move file the_file to folder todaysfolder
						set the label index of the_file to the 0
					end try
				end if
			end tell
		end repeat
		
	else
		-- move photos added to iPhoto from watch folder into the trash
		repeat with i from 1 to the number of items in added_items
			set the_file to item i of added_items
			tell application "Finder"
				if (file the_file exists) then
					try
						if (debug_mode is true) then say "Moving file to folder"
						
						move file the_file to trash
						set the label index of the_file to the 0
					end try
				end if
			end tell
		end repeat
	end if
	
end adding folder items to
edited for clarity.

Last edited by cudaboy_71; 03-30-2005 at 09:05 AM.
cudaboy_71 is offline   Reply With Quote
Old 03-30-2005, 04:30 PM   #7
mclbruce
Hall of Famer
 
Join Date: Mar 2002
Posts: 3,878
Thanks cudaboy 71. I'll mess around with this script and look for some others as well. My current goal is a script that lives in the Entourage scripts menu. It would open iPhoto automatically and do the import as well, similar to the way iPhoto will open an email client when you click the email button in iPhoto.
mclbruce is offline   Reply With Quote
Old 04-08-2005, 06:46 AM   #8
jokke
Prospect
 
Join Date: Jan 2002
Posts: 1
Tiger

Quote:
Originally Posted by mclbruce
When I'm in iPhoto it's easy to select a photo or two and click the email button and an email message gets created with the photos attached.

I wish it was just as easy to put photos received in email into iPhoto. Select the email message, press a button or key combo, and the photos attached to the message are added to iPhoto.

Mail in Tiger will do just this. Steve Jobs demonstrated this feature during the last keynote. A week or two and the wait will be over
jokke is offline   Reply With Quote
Reply

Thread Tools
Display Modes

Posting Rules
You may not post new threads
You may not post replies
You may not post attachments
You may not edit your posts

BB code is On
Smilies are On
[IMG] code is On
HTML code is Off

Forum Jump



All times are GMT -5. The time now is 06:46 PM.


Powered by vBulletin® Version 3.8.7
Copyright ©2000 - 2014, vBulletin Solutions, Inc.
Site design © IDG Consumer & SMB; individuals retain copyright of their postings
but consent to the possible use of their material in other areas of IDG Consumer & SMB.