App that burns across cds for large amounts of data

[vanillacoke]

Here is my problem, i'm hoping someone has a recommendation for software or maybe some applescript?

I'm always burning large amounts of image files from photoshoots. Usually in the 1.5 to 2 gig range. So i have to manually select the files in 700mb chunks to stick into toast. and then burn a few cds. (i know one big dvd would be ideal, but not everyone has a dvd drive so unfortunatley the 700mb cd is what we have to use)

Does anyone know of a program that will automatically burn as many cds as needed without any fuss or muss. And most importantly lets you name the cds.

Ie.

Client_DISK*

where * would be the disc number.

OR

And apple script that would take a folder of files and make subfolders that are 700mb in size and then a last folder that would be the remainder.

Thanks for any help!!! This would save me a TON of time.

vanillacoke.

[bramley]

If you do a search in these forums on spanning multiple CDs/DVDs you can get a number of possible utilities that may do as you want.

Here is one such thread: http://forums.macosxhints.com/showthread.php?t=19393

[vanillacoke]

Quote: Originally Posted by bramley If you do a search in these forums on spanning multiple CDs/DVDs you can get a number of possible utilities that may do as you want. Here is one such thread: http://forums.macosxhints.com/showthread.php?t=19393

Not quite. Anything previously mentioned is a backup app which creates the directory structure of the original file locations.

I'm looking for something that will see 2 GB of photoshop files and automatically burn just the files to 4 cds. No backup info or routines.

I just dont know why toast wont do this....

[acme.mail.order]

DVD read drives are pretty common on anything reasonably recent.

Are you working in an OSX-only environment? If yes, then you can use the `segment` option of hdiutil to split any folder up into sub-700Mb chunks and burn the chunks across several disks. Great advantage is rather seamless use at the other end. Otherwise, a more complicated script will be required to find files until a limit is reached, then burn these files to an ISO image. It's going to have to be custom-written - any Applescript gurus out there want to take it on?

[vanillacoke]

Quote: Originally Posted by acme.mail.order DVD read drives are pretty common on anything reasonably recent. Are you working in an OSX-only environment? If yes, then you can use the `segment` option of hdiutil to split any folder up into sub-700Mb chunks and burn the chunks across several disks. Great advantage is rather seamless use at the other end. Otherwise, a more complicated script will be required to find files until a limit is reached, then burn these files to an ISO image. It's going to have to be custom-written - any Applescript gurus out there want to take it on?

You'd think that dvd drives are pretty common. We have a client that is still on OS 8!!! and this is a client that works for a very large retail chain.... (that shall remain nameless). In fact the majority of people we deal with, while they work on compters, are not computer savy at all. They don't update anything, and if its working they dont change it. When you offer them a DVD they look at you like you are crazy....

I'll try the hdiutil! thanks for the tip. And hopefully someone with some mad applescript skills helps me out!

[JackeBoy]

and Macs' regular cd burner will allow you to do this... on my machine every time I have a large fill it prompts me to choose if i want to burn across multiple cd's. I will check when i get home and get back to you. All that has to be done is drop the files onto the disk copying area and tell it to burn.

I'll double check and let you know the exact process.

[aarony]

On the PC, there used to be a program called BurnToTheBrim that would organize files in different folders given a size (such as 700MB for a CD). Once the files were moved to different folders, you could simply drag the folders to your burning application and away you go.

I'm sure some AppleScripting guru could write such as an app.

[rusto]

Quote: Originally Posted by aarony On the PC, there used to be a program called BurnToTheBrim that would organize files in different folders given a size (such as 700MB for a CD). Once the files were moved to different folders, you could simply drag the folders to your burning application and away you go. I'm sure some AppleScripting guru could write such as an app.

I'd go for an AppleScript that would do just this! Maybe I'll dust off my script editor and get started...

[bramley]

The AS below copies a folder into a group of folders each no larger than the user defined maximum. It can only handle folders that contain no subfolders. This might sound like a bit of a restriction but a moments thought should show that it would be hard work working out what to do in the event that a sub-folder exceeds the maximum all on its own. Better to make the user get it right to begin with.

Save the script as an application - no startup screen. The script works as a droplet. Drop the folders on to it. The property max_size should be altered to reflect the size of output folders.

property default_path : path to desktop from user domain
property max_size : 650 (*value of maximum folder size in Mb*)
property max_bytes : max_size * 1024 * 1024
property folder_suffix : "Pt_" (*suffix to distinguish sub-folders*)

on open (these_folders)
	repeat with aItem in these_folders
		tell application "Finder"
			if class of item aItem is folder then
				if not (exists (some item in contents of aItem whose class is folder)) then
					set output_folder to choose folder with prompt "Select folder to place sub-folders in:" default location default_path
					set folder_list to {}
					set folder_counter to 1
					set total_size to 0
					set current_name to name of aItem as string
					repeat with aFile in contents of aItem
						if (total_size + (size of aFile) ? max_bytes) then
							my copy_files(output_folder, folder_counter, current_name, folder_list)
							set total_size to size of aFile
							set folder_list to {aFile as alias}
							set folder_counter to folder_counter + 1
						else
							set total_size to total_size + (size of aFile)
							set folder_list to folder_list & {aFile as alias}
						end if
					end repeat
					if (total_size > 0) then
						my copy_files(output_folder, folder_counter, current_name, folder_list)
					end if
				else
					display dialog ("WARNING: Item name: " & name of aItem as string) & return & "Cannot process this item. Contains subfolders" with icon stop
				end if
			else
				display dialog ("WARNING: Item name: " & name of aItem as string) & return & "Cannot process this item. It is not a folder" with icon stop
			end if
		end tell
	end repeat
end open

on copy_files(out_folder, counter, folder_name, list_of_folders)
	tell application "Finder"
		set current_name to folder_name & folder_suffix & (counter as string)
		set current_folder to make new folder at out_folder with properties {name:current_name}
		duplicate list_of_folders to current_folder
	end tell
end copy_files

[rusto]

Did you intend for the following line to have a "?" in it? If not, what should it be? Did you shift by mistake when you meant to type a "/"?

if (total_size + (size of aFile) ? max_bytes) then

[bramley]

Hmmm! Looks like the forum is translating the 'greater than or equal to' symbol i.e Unicode 2265 incorrectly.

If you substitute the following line for the one above then all should be well

if (total_size + (size of aFile) >= max_bytes) then

You will see that Script Editor coerces this to the correct symbol when you compile the script.

[griffman]

What happens if you just type Option-greater-than or Option-less-than, like this...

≥ ≤

Edit: Hmm, that looks like it worked...

-rob.

[bramley]

Umm!

Having just looked at this again I see I have made an error in the original script. The ASCII sorting can't have worked properly. Here is an edited script.

Click here to open this script in SE

property default_path : path to desktop from user domain
property max_size : 650 (*value of maximum folder size*)
property folder_suffix : "Pt_" (*suffix to distinguish sub-folders*)

on open (these_folders)
	repeat with aItem in these_folders
		tell application "Finder"
			if class of item aItem is folder then
				set output_folder to choose folder with prompt "Select folder to place sub-folders in:" default location default_path
				set response to display dialog "Enter max size (MB) of sub-folders:" default answer max_size
				set max_sub_folder_size to (text returned of response) as number
				set max_sub_folder_bytes to max_sub_folder_size * 1024 * 1024
				set file_list to name of (every file in contents of aItem)
				set sorted_list to my ASCII_Sort(file_list)
				set folder_list to {}
				set folder_counter to 1
				set total_size to 0
				repeat until (length of sorted_list = 0)
					set aFile to ((aItem as string) & first item of sorted_list) as alias
					if (total_size + (size of aFile) >= max_sub_folder_bytes) then
						my copy_files(output_folder, folder_counter, folder_list)
						set total_size to size of aFile
						set folder_list to {aFile}
						set folder_counter to folder_counter + 1
					else
						set total_size to total_size + (size of aFile)
						copy aFile to end of folder_list
					end if
					set sorted_list to rest of sorted_list
				end repeat
				if (total_size > 0) then
					my copy_files(output_folder, folder_counter, folder_list)
				end if
			else
				display dialog ("WARNING: Item name: " & name of aItem as string) & return & "Cannot process this item. It is not a folder" with icon stop
			end if
		end tell
	end repeat
end open

on ASCII_Sort(my_list)
	set the index_list to {}
	set the sorted_list to {}
	repeat (the number of items in my_list) times
		set the low_item to ""
		repeat with i from 1 to (number of items in my_list)
			if i is not in the index_list then
				set this_item to item i of my_list as text
				if the low_item is "" then
					set the low_item to this_item
					set the low_item_index to i
				else if this_item comes before the low_item then
					set the low_item to this_item
					set the low_item_index to i
				end if
			end if
		end repeat
		set the end of sorted_list to the low_item
		set the end of the index_list to the low_item_index
	end repeat
	return the sorted_list
end ASCII_Sort

on copy_files(out_folder, counter, folder_list)
	tell application "Finder"
		set current_name to (name of out_folder) & folder_suffix & (counter as string)
		set current_folder to make new folder at out_folder with properties {name:current_name}
		duplicate folder_list to current_folder
	end tell
end copy_files

[raider]

Quote: Originally Posted by vanillacoke Here is my problem, i'm hoping someone has a recommendation for software or maybe some applescript? I'm always burning large amounts of image files from photoshoots. Usually in the 1.5 to 2 gig range. So i have to manually select the files in 700mb chunks to stick into toast. and then burn a few cds. (i know one big dvd would be ideal, but not everyone has a dvd drive so unfortunatley the 700mb cd is what we have to use) Does anyone know of a program that will automatically burn as many cds as needed without any fuss or muss. And most importantly lets you name the cds. Thanks for any help!!! This would save me a TON of time. vanillacoke.

Check out DropDMG - it might be what you are looking for. It downloads as a fully functional time limited "demo" - however it is definately worth the $10 the developer is asking...

And the developer has been EXTREMELY responsive, and helpful - I was working with 20GB files that created problems. He quickly took my information, and worked on a fix - then released the fixed and improved version. I use the application to split up iMovie raw DV so I can archive it on DVD-R. Works nicely.