AAC encoding - iTunes or QuickTime

[Jacques]

I've discovered that AAC encoding via iTunes is of poor quality when compared to AAC encoding via QT. Various sources since AAC encoding debuted via iTunes have reported this. Here's one mention, see the last two paragraphs.

Is it possible to force iTunes to encode via QuickTime? What's the most efficient and economical way to use QT AAC encoding to keep the quality standards up?

Can anyone elaborate on this at all?

thanks for thoughts

Jacques

[Jacques]

There are two main applications that batch encode AAC, besides iTunes.

So far from what I gather, there are three settings to use in these encodings (good, better, and best). The stand-alone encoders (AACelerator and AAChoo) seem to use the BEST setting and iTunes (not adjustable via preferences) uses the GOOD setting.

See this FAQ from AAChoo's website.

--

Why oh WHY did Apple leave this option out? Anyone know how to hack iTunes on this one?

[Jacques]

This thread is all my own so far!

Alberto of Ovolab (makers of AAChoo) supplied me with these two (!@# and $%^), enjoy.

[Mikey-San]

I used iTunes to rip twenty or thirty CDs for my library a couple of weeks ago. I encoded in AAC at 160 Kbps. They sound just fine to me.

I dunno if I believe sites that say it's soooo bad, honestly. 128 might be noticeable to some people, but at 160 and higher, people complain just to complain, I think. (I mean, not everyone has $5,000 speakers, perfect ears, and perfectly quiet areas where they listen to music. Usually, I'm at work or playing Quake or something while I'm listening. That, or there's other background noise that makes the difference between 256 and 320 simply bigger file size. ;-))

It reminds me of this:

http://home.cfl.rr.com/happysurfer/audio_bs.htm

;-)

[tsugaru]

Use Quicktime 6.3 Pro and use the AAC Best setting if you are a true audiophile.

Otherwise, you can be like me and use iTunes 320kbps Stereo CBR AAC encoding which sounds just fine through my Sony headphones and Apple Pro Speakers.

[SunByrne]

I also prefer QT's "best" setting to iTunes, though of course it's faster with
iTunes. When I want to rip a new CD to decide which songs I'm going to keep, I
just use iTunes, but I go back to QT when it's more of a "final" rip.

I manage this with an AppleScript, which I store in /Library/iTunes/Scripts/.
This script assumes you have a QT settings file which uses the settings you
want at the location "HD:Users:<username>:Music:qtsettings:AACBest" (you'll
want to edit that path to your own username both there and in the music
location). Pop in a CD, select the tracks to rip, and then run the script off
the menu.

tell application "iTunes"
	activate
	repeat with Trk in the selection
		set TInfo to {album of Trk, artist of Trk, year of Trk, genre of Trk, track number of Trk, track count of Trk, composer of Trk}
		set TrkName to name of Trk
		set NewFile to my AAC(location of Trk, TrkName)
		-- activate
		set NewTrk to add (NewFile as alias)
		set name of NewTrk to TrkName
		set album of NewTrk to item 1 of TInfo
		set artist of NewTrk to item 2 of TInfo
		set year of NewTrk to item 3 of TInfo
		set genre of NewTrk to item 4 of TInfo
		set track number of NewTrk to item 5 of TInfo
		set track count of NewTrk to item 6 of TInfo
		set composer of NewTrk to item 7 of TInfo
	end repeat
	activate
	beep
	beep
end tell

on AAC(InFile, name)
	set OutFolder to "HD:Users:<username>:Music:iTunes:iTunes Music:"
	set OutPath to (OutFolder & my hackName(name) & ".m4a")
	tell application "QuickTime Player"
		--activate
		open InFile
		with timeout of 600 seconds
			export movie 1 to (file OutPath) as MPEG4 using settings (alias "Sol:Users:sunburn:Music:qtsettings:AAC160Best")
		end timeout
		close movie 1
	end tell
	tell application "Finder"
		set creator type of (file OutPath) to "hook"
		set file type of (file OutPath) to "M4A "
		update (file OutPath)
	end tell
	return OutPath
end AAC

on stripExt(InName)
	set OTID to AppleScript's text item delimiters
	set AppleScript's text item delimiters to "."
	set TheItems to text items of InName
	set NewName to items 1 thru ((length of TheItems) - 1) of TheItems
	set NewName to NewName as text
	set AppleScript's text item delimiters to OTID
	return NewName
end stripExt

on hackName(InName)
	if length of InName < 28 then
		return InName
	else
		set OTID to AppleScript's text item delimiters
		set AppleScript's text item delimiters to " "
		set OutName to ""
		set TheItems to text items of InName
		set Counter to 1
		repeat until length of OutName > 27
			set OutName to items 1 thru Counter of TheItems as text
			set Counter to Counter + 1
		end repeat
		set OutName to items 2 thru (Counter - 2) of TheItems as text
		--
		set AppleScript's text item delimiters to OTID
		return OutName
	end if
end hackName

[edit: fold -mt]